Showing results 1 to 3 of 3

Thread: Zugriff auf Formelvariablen in Combielement

  1. #1
    Join Date
    29.07.2007
    Location
    Germany
    Posts
    194

    Frage Zugriff auf Formelvariablen in Combielement

    Hallo an alle!

    Ich suche eine Möglichkeit per VBA alle in einem Bild benutzten Variablen auszulesen.

    Wir nutzen zu 90% das Combielement und die Variablen werden darin als Formelvariablen hinterlegt um die Animationen zu definieren.



    Ich finde keine Möglichkeit die Formelvariablen über VBA anzusprechen!

    Auf welchem Weg komme ich per VBA an die Formelvariablen in einem Combielement heran?


    Ich bin für jede Hilfe dankbar!

    H.-P.

  2. #2
    robertf Gast

    Default Re: Zugriff auf Formelvariablen in Combielement

    Hallo hp!

    hier ein Beispiel zur Frage...

    Option Explicit
    
    Dim zPRJ As Project
    Dim zPIC As DynPicture
    Dim zELE As Element
    Dim zVAR As Variable
    Dim strPropertyString As String
    Dim nCount As Integer
    
    Public Sub ReadCombi()
    Dim i As Integer
      'get project object
      Set zPRJ = MyWorkspace.ActiveDocument
      'get picture object
      Set zPIC = zPRJ.DynPictures.Item("START")
      'get element object (Combielement)
      Set zELE = zPIC.Elements.Item("Combielement_1")
      'Get Variable Count from element
      nCount = zELE.DynProperties("DynEleVar[-1]")
      'Enum Variables
      For i = 0 To nCount - 1
        'create dynproperty string...
        strPropertyString = "DynEleVar[" & i & "].SymVarName"
        'get varname
        Debug.Print "X" & Format((i + 1), "00") & ": " & zELE.DynProperties(strPropertyString)
        'create dynproperty string...
        strPropertyString = "DynEleVar[" & i & "].ProjectVar"
        'get variable object
        Set zVAR = zELE.DynProperties(strPropertyString)
        If Not zVAR Is Nothing Then Debug.Print "Object: " & zVAR.Name
      Next i
    End Sub
    
    Public Sub Combi_AddVar()
      'get project object
      Set zPRJ = MyWorkspace.ActiveDocument
      'get picture object
      Set zPIC = zPRJ.DynPictures.Item("START")
      'get element object (Combielement)
      Set zELE = zPIC.Elements.Item("Combielement_1")
      'get variable object
      Set zVAR = zPRJ.Variables.Item("WIZ_VAR_13")
      'Get Variable Count
      nCount = zELE.DynProperties("DynEleVar[-1]")
      'add new DynProperty : DynEleVar
      zELE.CreateDynProperty ("DynEleVar")
      'create dynproperty string...
      strPropertyString = "DynEleVar[" & nCount & "].ProjectVar"
      'add variable to element
      zELE.DynProperties(strPropertyString) = zVAR.Name
    End Sub

    Ich hoffe da ist das gewünschte dabei...
    Attached Files Attached Files

  3. #3
    Join Date
    29.07.2007
    Location
    Germany
    Posts
    194

    Reden AW: Zugriff auf Formelvariablen in Combielement

    Super, danke Robert!

    Jetzt komme ich endlich mit meinem Projekt voran.


    Gruß,

    H.-P.
    string zenon = "7.60 Build61612 / 8.00 Build62073/ 8.10 Build62573";
    string Windows = "7 / 10 / 2016";
    string VMware = "Workstation / VMware ESXi";

Posting Rules

  • You may not post new threads
  • You may not post replies
  • You may not post attachments
  • You may not edit your posts
  •